DateAndTime.DateSerial(Int32, Int32, Int32) Método

public:
 static DateTime DateSerial(int Year, int Month, int Day);

public static DateTime DateSerial(int Year, int Month, int Day);

static member DateSerial : int * int * int -> DateTime

Public Function DateSerial (Year As Integer, Month As Integer, Day As Integer) As DateTime

Parámetros

Devoluciones

Valor que representa el año, el mes y el día especificados, con la información de hora establecida en medianoche (00:00:00).

Ejemplos

En este ejemplo se usa la DateSerial función para devolver la fecha del año, mes y día especificados.

' DateSerial returns the date for a specified year, month, and day.
Dim aDate As Date
' Variable aDate contains the date for February 12, 1969.
aDate = DateSerial(1969, 2, 12)
Console.WriteLine(aDate)

' The following example uses DateSerial to determine and display
' the last day of the previous month.
' First, establish a starting date.
Dim startDate = #1/23/1994#
' The 0 for the day represents the last day of the previous month.
Dim endOfLastMonth = DateSerial(startDate.Year, startDate.Month, 0)
Console.WriteLine("Last day in the previous month: " & endOfLastMonth)

' The following example finds and displays the day of the week that the 
' 15th day of the following month will fall on.
Dim fifteenthsDay = DateSerial(Today.Year, Today.Month + 1, 15)
Console.WriteLine("The 15th of next month is a {0}", fifteenthsDay.DayOfWeek)

Comentarios

Los valores de dos dígitos para el argumento se interpretan en función de la configuración del equipo definida por el Year usuario. La configuración predeterminada es que los valores comprendidos entre 0 y 29 se interpretan como los años 2000-2029 y los valores comprendidos entre 30 y 99 se interpretan como los años 1930-1999. Para firmar todos los demás años, use un año de cuatro dígitos, por ejemplo, 1924.

En el ejemplo siguiente se muestran valores de argumento negativo, cero y positivo. Aquí, la DateSerial función devuelve un Date objeto que representa el día anterior al primer día de marzo del año 10 años antes del año actual; es decir, el último día de febrero hace diez años.

Dim EndFeb As Date = DateSerial(-10, 3, 0)

Si o MonthDay supera su intervalo normal, se aplica a la siguiente unidad más grande según corresponda. Por ejemplo, si especifica 32 días, se evalúa como un mes y de uno a cuatro días, según el valor de Month. Si Year es mayor que 9999 o si algún argumento está fuera del intervalo -2.147.483.648 a 2.147.483.647, se produce un ArgumentException error. Si la fecha especificada por los tres argumentos es anterior a las 00:00:00 del 1 de enero del año 1 o posterior a las 23:59:59 del 31 de diciembre de 9999, se produce un ArgumentOutOfRangeException error.

El Date tipo de datos incluye componentes de hora. DateSerial establece todos estos valores en 0, por lo que el valor devuelto representa el principio del día calculado.

Dado que cada Date valor es compatible con una DateTime estructura, sus métodos proporcionan opciones adicionales para ensamblar un Date valor. Por ejemplo, puede usar uno de los constructores sobrecargados DateTime para rellenar una Date variable mediante la combinación deseada de componentes. En el ejemplo siguiente se establece NewDateTime el 6 de mayo de 1978 en una décima de segundo antes de las 8:30 de la mañana:

Dim NewDateTime As Date = New Date(1978, 5, 6, 8, 29, 59, 900)

Consulte también

• DateValue(String)
• Day(DateTime)
• Month(DateTime)
• Now
• TimeSerial(Int32, Int32, Int32)
• TimeValue(String)
• Weekday(DateTime, FirstDayOfWeek)
• Year(DateTime)
• System
• Resumen de tipos de datos (Visual Basic)