Snabbstart: Distribuera din första Azure-resurs med AzAPI Terraform-providern

Terraform möjliggör definition, förhandsversion och distribution av molninfrastruktur. Med Terraform skapar du konfigurationsfiler med hjälp av HCL-syntax. Med HCL-syntaxen kan du ange molnleverantören – till exempel Azure – och de element som utgör din molninfrastruktur. När du har skapat konfigurationsfilerna skapar du en körningsplan som gör att du kan förhandsgranska ändringarna i infrastrukturen innan de distribueras. När du har verifierat ändringarna tillämpar du utförandeplanen för att distribuera infrastrukturen.

AzAPI Terraform-providern hanterar Azure resurser direkt via Azure Resource Manager-API:et. Det är särskilt användbart för resurser, egenskaper eller API-versioner som ännu inte stöds av AzureRM. I det här exemplet använder du azapi_resource för att skapa en Azure Container Registry.

Förutsättningar

• Azure-prenumeration: Om du inte har en Azure-prenumeration skapar du ett kostnadsfritt konto innan du börjar.

• Konfigurera Terraform: Om du inte redan har gjort det konfigurerar du Terraform med något av följande alternativ:

  • Konfigurera Terraform i Azure Cloud Shell med Bash
  • Konfigurera Terraform i Azure Cloud Shell med PowerShell
  • Konfigurera Terraform i Windows med Bash
  • Konfigurera Terraform i Windows med PowerShell

När du loggar in på Azure-portalen med ett Microsoft-konto används standardprenumerationen för det kontot.

Terraform autentiserar automatiskt med hjälp av information från standardprenumerationen i Azure.

Kör az account show för att verifiera det aktuella Microsoft-kontot och Azure-prenumerationen.

az account show

Alla ändringar du gör via Terraform finns i den azure-prenumeration som visas. Om det är vad du vill kan du hoppa över resten av den här artikeln.

Implementera den Terraform-koden

1. Skapa en katalog där du kan testa Terraform-exempelkoden och göra den till den aktuella katalogen.

2. Skapa en fil med namnet providers.tf och infoga följande kod:

   terraform {
     required_providers {
       azapi = {
         source = "Azure/azapi"
         version = "~>2.0"
       }
       azurerm = {
         source  = "hashicorp/azurerm"
         version = "~>4.0"
       }
       random = {
         source  = "hashicorp/random"
         version = "~>3.0"
       }
     }
   }
   
   provider "azurerm" {
     features {}
   }
   

3. Skapa en fil med namnet variables.tf och infoga följande kod:

   variable "resource_group_location" {
     type        = string
     default     = "eastus"
     description = "Location of the resource group."
   }
   
   variable "resource_group_name_prefix" {
     type        = string
     default     = "rg"
     description = "Prefix of the resource group name that's combined with a random ID so name is unique in your Azure subscription."
   }
   
   variable "container_registry_name" {
     type        = string
     default     = ""
     description = "Name of the container registry."
   }
   

4. Skapa en fil med namnet main.tf och infoga följande kod:

   # Create a resource group with a random name.
   resource "random_pet" "rg_name" {
     prefix = var.resource_group_name_prefix
   }
   
   resource "azurerm_resource_group" "rg" {
     location = var.resource_group_location
     name     = random_pet.rg_name.id
   }
   
   # Create a user assigned identity resource.
   resource "azurerm_user_assigned_identity" "example" {
     name                = "example"
     resource_group_name = azurerm_resource_group.rg.name
     location            = azurerm_resource_group.rg.location
   }
   
   # Create a random name for the container registry.
   resource "random_string" "acr_name" {
     length  = 10
     special = false
     upper   = false
     numeric = false
   }
   
   # Manage a container registry resource.
   resource "azapi_resource" "example" {
     type      = "Microsoft.ContainerRegistry/registries@2020-11-01-preview"
     name      = coalesce(var.container_registry_name, random_string.acr_name.result)
     parent_id = azurerm_resource_group.rg.id
   
     location = azurerm_resource_group.rg.location
     identity {
       type         = "SystemAssigned, UserAssigned"
       identity_ids = [azurerm_user_assigned_identity.example.id]
     }
   
     body = {
       sku = {
         name = "Standard"
       }
       properties = {
         adminUserEnabled = true
       }
     }
   
     tags = {
       "Key" = "Value"
     }
   
     response_export_values = ["properties.loginServer", "properties.policies.quarantinePolicy.status"]
   }
   

5. Skapa en fil med namnet outputs.tf och infoga följande kod:

   output "resource_group_name" {
     value = azurerm_resource_group.rg.name
   }
   
   output "azure_container_registry_name" {
     value = azapi_resource.example.name
   }
   

Initiera Terraform

Kör terraform init för att initiera Terraform-distributionen. Det här kommandot laddar ned den Azure-provider som krävs för att hantera dina Azure-resurser.

terraform init -upgrade

Viktiga punkter:

• Parametern -upgrade uppgraderar nödvändiga provider-plugin-program till den senaste versionen som uppfyller konfigurationens versionsbegränsningar.

Skapa en Terraform-körningsplan

Kör terraform plan för att skapa en utförandeplan.

terraform plan -out main.tfplan

Viktiga punkter:

• Kommandot terraform plan skapar en körningsplan, men kör den inte. I stället avgör den vilka åtgärder som krävs för att skapa den konfiguration som anges i konfigurationsfilerna. Med det här mönstret kan du kontrollera om utförandeplanen matchar dina förväntningar innan du gör några ändringar i de faktiska resurserna.
• Med den valfria -out parametern kan du ange en utdatafil för planen. Med hjälp av parametern -out ser du till att planen du granskade är exakt vad som tillämpas.

Tillämpa en körningsplan för Terraform

Kör terraform apply för att genomföra körningsplanen till din molninfrastruktur.

terraform apply main.tfplan

Viktiga punkter:

• terraform apply Exempelkommandot förutsätter att du tidigare körde terraform plan -out main.tfplan.
• Om du har angett ett annat filnamn för parametern -out använder du samma filnamn i anropet till terraform apply.
• Om du inte använde parametern -out anropar terraform apply du utan några parametrar.

Verifiera resultatet

Rensa resurser

Gör följande när du inte längre behöver de resurser som skapats via Terraform:

1. Kör terraform plan och ange destroy.

   terraform plan -destroy -out main.destroy.tfplan
   

   Viktiga punkter:

   • Kommandot terraform plan skapar en körningsplan, men kör den inte. I stället avgör den vilka åtgärder som krävs för att skapa den konfiguration som anges i konfigurationsfilerna. Med det här mönstret kan du verifiera om utförandeplanen matchar dina förväntningar innan du gör några ändringar i verkliga resurser.
   • Med den valfria -out parametern kan du ange en utdatafil för planen. Med hjälp av parametern -out ser du till att planen du granskade är exakt vad som tillämpas.

2. Kör terraform apply för att tillämpa körningsplanen.

   terraform apply main.destroy.tfplan
   

Felsöka Terraform i Azure

Felsöka vanliga problem när du använder Terraform i Azure

Nästa steg