Snabbstart: Utföra Azure resursåtgärder med AzAPI Terraform-providern

Terraform möjliggör definition, förhandsversion och distribution av molninfrastruktur. Med Terraform skapar du konfigurationsfiler med hjälp av HCL-syntax. Med HCL-syntaxen kan du ange molnleverantören – till exempel Azure – och de element som utgör din molninfrastruktur. När du har skapat konfigurationsfilerna skapar du en körningsplan som gör att du kan förhandsgranska ändringarna i infrastrukturen innan de distribueras. När du har verifierat ändringarna tillämpar du genomförandeplanen för att implementera infrastrukturen.

Använd azapi_resource_action som en hanterad Terraform-resurs för att utföra imperativa, tillståndsförändrande åtgärder på Azure resurser. I det här exemplet skapar du ett Azure lagringskonto och roterar sedan dess åtkomstnycklar.

azapi_resource_action har två användningsformulär:

  • Resurs: Utför en tillståndsändringsåtgärd under terraform apply. Terraform spårar åtgärden i statusen och kan återställa den på terraform destroy.
  • Datakälla: Utför en skrivskyddad åtgärd under planeringen. Se snabbstartguiden för datakälla för resursåtgärd för det scenariot.

Använd resursformuläret när du behöver Terraform för att utföra en Azure åtgärd som inte baseras på en standardlivscykel för att skapa/läsa/uppdatera/ta bort– till exempel rotera autentiseringsuppgifter, starta eller stoppa en virtuell dator eller utlösa en redundansväxling.

  • Skapa ett lagringskonto med AzureRM-providern
  • Rotera åtkomstnyckeln för lagringskontot med azapi_resource_action

Förutsättningar

  • Azure-prenumeration: Om du inte har en Azure-prenumeration skapar du ett kostnadsfritt konto innan du börjar.

När du loggar in på Azure-portalen med ett Microsoft-konto används standardprenumerationen för det kontot.

Terraform autentiserar automatiskt med hjälp av information från standardprenumerationen i Azure.

Kör az account show för att verifiera det aktuella Microsoft-kontot och Azure-prenumerationen.

az account show

Alla ändringar du gör via Terraform finns i den azure-prenumeration som visas. Om det är vad du vill kan du hoppa över resten av den här artikeln.

Utför implementeringen av Terraform-koden

  1. Skapa en katalog där du kan testa Terraform-exempelkoden och göra den till den aktuella katalogen.

  2. Skapa en fil med namnet providers.tf och infoga följande kod:

    terraform {
  required_providers {
    azapi = {
      source  = "Azure/azapi"
      version = "~> 2.0"
    }
    azurerm = {
      source  = "hashicorp/azurerm"
      version = "~> 4.0"
    }
    random = {
      source  = "hashicorp/random"
      version = "~> 3.0"
    }
  }
}

provider "azurerm" {
  features {}
}

provider "azapi" {}

  3. Skapa en fil med namnet variables.tf och infoga följande kod:

    variable "resource_group_location" {
  type        = string
  default     = "eastus"
  description = "Location of the resource group."
}

variable "resource_group_name_prefix" {
  type        = string
  default     = "rg"
  description = "Prefix of the resource group name that's combined with a random value to create a unique name."
}

variable "storage_account_name_prefix" {
  type        = string
  default     = "st"
  description = "Prefix of the storage account name that's combined with a random value to create a unique name."
}

  4. Skapa en fil med namnet main.tf och infoga följande kod:

    resource "random_pet" "rg_name" {
  prefix = var.resource_group_name_prefix
}

resource "random_string" "storage_suffix" {
  length  = 8
  upper   = false
  special = false
}

resource "azurerm_resource_group" "example" {
  location = var.resource_group_location
  name     = random_pet.rg_name.id
}

resource "azurerm_storage_account" "example" {
  name                     = "${var.storage_account_name_prefix}${random_string.storage_suffix.result}"
  resource_group_name      = azurerm_resource_group.example.name
  location                 = azurerm_resource_group.example.location
  account_tier             = "Standard"
  account_replication_type = "LRS"
}

resource "azapi_resource_action" "regenerate_key" {
  type        = "Microsoft.Storage/storageAccounts@2023-01-01"
  resource_id = azurerm_storage_account.example.id
  action      = "regenerateKey"
  method      = "POST"

  body = {
    keyName = "key1"
  }
}

    Viktiga punkter om att använda azapi_resource_action som resurs:

    • Fältet action anger arm-åtgärden som ska utföras. För nyckelrotation för lagringskonto använder du regenerateKey.
    • Fältet method anger HTTP-metoden. De flesta imperativa åtgärder använder POST.
    • Attributet body skickar data till åtgärden. För nyckelregenerering anger du vilken nyckel (key1 eller key2) som ska roteras.
    • Åtgärden utförs under terraform apply och spåras i Terraform-tillstånd.

  5. Skapa en fil med namnet outputs.tf och infoga följande kod:

    output "resource_group_name" {
  value = azurerm_resource_group.example.name
}

output "storage_account_name" {
  value = azurerm_storage_account.example.name
}

Kör terraform init för att initiera Terraform-distributionen. Det här kommandot laddar ned den Azure-provider som krävs för att hantera dina Azure-resurser.

terraform init -upgrade

Viktiga punkter:

  • Parametern -upgrade uppgraderar nödvändiga provider-plugin-program till den senaste versionen som uppfyller konfigurationens versionsbegränsningar.

Kör terraform plan för att skapa en utförandeplan.

terraform plan -out main.tfplan

Viktiga punkter:

  • Kommandot terraform plan skapar en utförandeplan, men utför den inte. I stället avgör den vilka åtgärder som krävs för att skapa den konfiguration som anges i konfigurationsfilerna. Med det här mönstret kan du kontrollera om åtgärdsplanen stämmer överens med dina förväntningar innan du gör några ändringar i faktiska resurser.
  • Med den valfria parametern -out kan du ange en utdatafil för planen. Med hjälp av parametern -out ser du till att den plan som du har granskat är exakt vad som tillämpas.

Kör terraform apply för att applicera genomförandeplanen på din molninfrastruktur.

terraform apply main.tfplan

Viktiga punkter:

  • terraform apply Exempelkommandot förutsätter att du tidigare körde terraform plan -out main.tfplan.
  • Om du har angett ett annat filnamn för parametern -out använder du samma filnamn i anropet till terraform apply.
  • Om du inte använde parametern -out anropar du terraform apply utan några parametrar.

Verifiera resultatet

När terraform apply är klart har lagringskontonyckeln roterats. Du kan verifiera nyckelrotationen genom att kontrollera lagringskontonycklarna i Azure.

Kör az storage account keys list för att visa lagringskontonycklarna.

```azurecli
az storage account keys list \
  --resource-group <resource_group_name> \
  --account-name <storage_account_name>
```

The `value` field shows the current key.

Exempel på andra resursåtgärder

Resursen azapi_resource_action fungerar med många Azure åtgärder. Här är vanliga exempel:

  • Virtual Machines: deallocate, start, restart, powerOff, reimage
  • Key Vaults: purge (för mjukt borttagna valv), rotate (för hanterade nycklar)
  • App Services: swap (för distributionsplatser), restart
  • Databaser: failover, promote
  • Compute-resurser: Alla åtgärder som exponeras av Azure REST API som ändrar tillståndet utan att skapa eller förstöra en resurs

Rensa resurser

Gör följande när du inte längre behöver de resurser som skapats via Terraform:

  1. Kör terraform plan och specificera flaggan destroy.

    terraform plan -destroy -out main.destroy.tfplan

    Viktiga punkter:

    • Kommandot terraform plan skapar en utförandeplan, men utför den inte. I stället avgör den vilka åtgärder som krävs för att skapa den konfiguration som anges i konfigurationsfilerna. Med det här mönstret kan du kontrollera om åtgärdsplanen stämmer överens med dina förväntningar innan du gör några ändringar i faktiska resurser.
    • Med den valfria parametern -out kan du ange en utdatafil för planen. Med hjälp av parametern -out ser du till att den plan som du har granskat är exakt vad som tillämpas.

  2. Kör terraform apply för att tillämpa genomförandeplanen.

    terraform apply main.destroy.tfplan

Felsöka Terraform på Azure

Felsök vanliga problem när du använder Terraform på Azure

Nästa steg

Översikt över Terraform AzAPI-provider

Lär dig hur du använder resursåtgärden AzAPI som datakälla

  • Last updated on